-- Open Links
-- https://c-command.com/scripts/omnifocus/open-links
-- Summary: Treats the text of the selected actions as URLs and opens them.
-- Requires: OmniFocus Pro
-- Install Location: ~/Library/Scripts/Applications/OmniFocus/
-- Last Modified: 2019-10-02



on run {}
    repeat with _action in my selectedActions()
        my processAction(_action)
    end repeat
end run

on selectedActions()
    tell application "OmniFocus"
        return my filterValues(my selectedValues(), {inbox task, task, available task, remaining task})
    end tell
end selectedActions

on selectedValues()
    tell application "OmniFocus"
        return value of selected trees of content of first document window of front document
    end tell
end selectedValues

on filterValues(_values, _classes)
    tell application "OmniFocus"
        set _result to {}
        repeat with _value in _values
            if _classes contains _value's class then
                copy _value to end of _result
            end if
        end repeat
        return _result
    end tell
end filterValues

on processAction(_action)
    tell application "OmniFocus"
        set _url to _action's name
        do shell script "open " & _url's quoted form
    end tell
end processAction